KVR Audio

Tony Ostinato · Post by **Tony Ostinato** » Wed Jul 29, 2015 7:36 am

hi,

i am begging for a vst midi octave switch plugin, so that when i step on a pedal the midi is momentarily transposed up an octave, or down even. i play on using an expression pedal

i play one of those yamaha wx5 wind controllers that looks like a soprano sax/clarinet and i can play bass lines but doing a lot of octave jumping wears the heck out of my left thumb and isnt that great on the octave keys.

went net searching for a plugin that would do this and man theres nothing

thanks!!

lfm · Post by **lfm** » Wed Jul 29, 2015 9:33 am

Sometimes it's finding the right terms:
did you look at transpose which is really this done by 12 half steps, and is immediate.

Look at Insert Piz here on KVR there are free VSTs that do this.

You don't tell about you situation, if with a daw.
Most daws allow to put a VST parameter knob on a track that can be controlled from external controller.

Or anyway through midi learn something.

Then ordinary footswitch midi pedal of some sort.

It should be doable.

Tony Ostinato · Post by **Tony Ostinato** » Wed Jul 29, 2015 10:07 am

its a live realtime setup.

kinda sorta have it working with piz force to range and a roland sustain footswitch thru my midi expression quattro.

yeah i can find transpose but having those extra steps in between mucks things up, i just really need a clean octave but from the expression pedal with maybe assignable cutoff point on the pedal where it does the switch.

heres my whole setup pretty much:

https://www.youtube.com/watch?v=l5ar_3nGx2w

Chris-S · Post by **Chris-S** » Wed Jul 29, 2015 3:49 pm

Are you using Reaper? I have a litte JS plugin, which is maybe doing what you want.

Code: Select all

desc:MidiOctaveSwitcher

/*********************************************************************
MidiOctaveSwitcher v1.0
for Reaper 4.60+
freeware by chris-s 
*********************************************************************/

slider1:0<0,127,1>Pedal
slider2:0<0,1,1>Octave offset

in_pin:none
out_pin:none

@init

// ext_noinit=1;

NOTE_OFF    = 8;
NOTE_ON     = 9;

oct = 0;

arr = 0;
i0=0; 
while(i0<128)(arr[i0]=0; i0+=1;);


@slider

oct = slider1 / 64 | 0;
oct > 1 ? oct = 1;

slider2 = oct;


@block

while (
  input = midirecv(mpos, msg, data1, data2);
  input ? (
    statusHi = (msg/16) | 0;
    statusLo =  msg&15;

    statusHi==NOTE_ON && data2==0 ? statusHi=NOTE_OFF;

    data1n=data1;
    data2n=data2;
      
    statusHi==NOTE_ON && data1<116 ? ( data1n = data1 + oct*12 ; arr[data1]=oct; );

    statusHi==NOTE_OFF && data1<116 ? ( oct0=arr[data1]; data1n = data1 + oct0*12; );
    
    midisend(mpos, msg, data1n, data2n);
  );
  
  input;
);

// end

Copy to the Reaper Effects dir.

Link the pedal slider to your controller.

Note: This is only for Live-play because the pedal movement is not recorded.

Tony Ostinato · Post by **Tony Ostinato** » Wed Jul 29, 2015 11:51 pm

"effect has code error in init 'around line 26' while (i0<128)(arr [i0]=0; i0+=1;);"

i may have done something wrong ive never messed with one of these, looks fricken fascinating tho and super thanks, im interested to learn more about all this, it might be pretty handy.

Chris-S · Post by **Chris-S** » Thu Jul 30, 2015 9:14 am

Whats your Reaper version (mine is 4.78)?

There should be no space-char between arr and [i0].

MaxSynths · Post by **MaxSynths** » Thu Jul 30, 2015 10:40 am

If you are on 32bit and SE it's not a problem for you I can try to put something together for you...

chroma · Post by **chroma** » Thu Jul 30, 2015 12:25 pm

You just need a midi effect for transpose 12 semitones. Put it in the track, map the footswitch to enable/disable it (especially good if this can be momentary) then you're done...

this shouldn't go through all the semitones... you don't want to connect it to the transpose amount, you want to connect it to the on/off...

Chris-S · Post by **Chris-S** » Thu Jul 30, 2015 2:26 pm

Hi,
here is another version with "internal linking".
Works also in record mode.

With "filter" you can enable the "eating" of the CC event.

Code: Select all


desc:MidiOctaveSwitcher2

/*********************************************************************
MidiOctaveSwitcher2 v1.0
for Reaper 4.60+
no rights reserved 
*********************************************************************/

slider1:64<0,127,1>CC No.
slider2:1<0,1,1{no,yes}>Filter CC

in_pin:none
out_pin:none


@init

// ext_noinit=1;

NOTE_OFF    = 8;
NOTE_ON     = 9;
CC_MSG      = 11;

oct = 0;
cc = 64;
filter = 1;

arr = 0;
i0=0; 
while(i0<128)(arr[i0]=0; i0+=1;);


@slider

cc = slider1 | 0;
filter = slider2;


@block

while (
  input = midirecv(mpos, msg, data1, data2);
  input ? (
    statusHi = (msg/16) | 0;
    statusLo =  msg&15;
    filt = 0;
  
    statusHi==NOTE_ON && data2==0 ? statusHi=NOTE_OFF;


    data1n=data1;
    data2n=data2;
    

    statusHi==CC_MSG && data1==cc ? ( oct = data2 / 64 | 0; oct>1 ? oct=1; filter ? filt=1; );

  
  
    statusHi==NOTE_ON && data1<116 ? ( data1n = data1 + oct*12 ; arr[data1]=oct; );

    statusHi==NOTE_OFF && data1<116 ? ( oct0=arr[data1]; data1n = data1 + oct0*12; );
  
    
    filt==0 ? midisend(mpos, msg, data1n, data2n);
  );
  
  input;
);

// end

Tony Ostinato · Post by **Tony Ostinato** » Thu Jul 30, 2015 8:12 pm

enabling/disablling reacts a little slow.

im still getting the errors with the jsfx, my test setup is 4.33 and my live stage setup is even older. im really skittish about updating the live setup because its so reliable. more likely ill do a new setup with a new laptop soon.

i am 64 bit.

hey super thanks for all the considerations, i know its a weird thing.

dformd · Post by **dformd** » Thu Jul 30, 2015 8:31 pm

you can do this with the standalone beta of Bidule

Chris-S · Post by **Chris-S** » Fri Jul 31, 2015 8:15 am

Tony Ostinato wrote: im still getting the errors with the jsfx, my test setup is 4.33 and my live stage setup is even older.

Ok, my code is for 4.60+.

Never change a running system...

Tony Ostinato · Post by **Tony Ostinato** » Fri Jul 31, 2015 9:29 am

once i get out of the busy season i can mess with updates more. i can do a full backup and then try things at will. thats not till like february tho.

it could be that im not supposed to be playing bass with a windsynth. i dont wanna fight the universe.

kohitsu · Post by **kohitsu** » Fri Jul 31, 2015 11:13 am

You can download reaper's JS as a separate vst plugin, ReaJS, and load Chris's script in that maybe:
http://www.reaper.fm/reaplugs/

Tony Ostinato · Post by **Tony Ostinato** » Sat Aug 01, 2015 9:37 am

aha! thanks, that worked and the scripts for the octave switchers load and work.

my live rig is bagged up because i played yesterday and again today so i havent gotten to really mess with it, probably monday or tuesday but it looks real good from what i can tell on the net laptop here.

ultra thanks all!

begging for a midi octave switch plugin, so that when i step on a pedal the midi is momentarily.....